[AppleScript]Illustrator別名で保存と書き出し

エラー制御をいっさい考えていない自分用

ai→eps
ai→PNG24
の
同時書き出しのサンプル

epsは別名で保存
PNG24は書き出し

なので
ちょっと処理が違います。

オプションを変更すれば
PDFで保存等にも使えますね。
参考にしてください。

↓EPSに別名で保存

↓PNG24書き出し

それぞれのオプションがありますね。

作成動作環境
10.6x
Adobe Illustrator CS4
 

on open DropObj

--------ファインダ呼び出し

tell application "Finder"

--------ファインダ　アクティブ

activate

--------繰り返しの始まり

repeat with ObjFiles in DropObj

--------ファイル名を取得

set fileName to name of ObjFiles as string

--------パスを取得

set pathAliasDoc to ObjFiles as alias

--------パスを文字列に変換

set pathStringDoc to pathAliasDoc as string

--------拡張子を判定

set exeName to name extension of ObjFiles

--------ファイル名から拡張子を取り除く

set MainFileName to my replace(fileName, "." & exeName, "") as string

---------フルパスからファイル名を抜いてディレクトリ名を作る

set pathStringDirName to my replace(pathStringDoc, fileName, "") as string

--------EPSファイル名を定義(EPS書き出しするので拡張子をepsに変更）

set the epsFileName to the (the MainFileName & "." & "eps") as string

--------EPS用にディレクトリ名とファイル名をつないでパスにしておく

set saveEpsFileName to (pathStringDirName & ":" & epsFileName) as string

--------PNG24ファイル名を定義(PNG24書き出しするので拡張子をpngに変更）

set the pngFileName to the (the MainFileName & "." & "png") as string

--------PNG24用にディレクトリ名とファイル名をつないでパスにしておく

set savePngFileName to (pathStringDirName & ":" & pngFileName) as string

--------Illustrator呼び出し

tell application "Adobe Illustrator"

--------呼び出し確認

launch

--------Illustrator　アクティブ

activate

--------ファイルを開く

open pathAliasDoc without dialogs

--------開いたファイルをactivDocとして定義

set activDoc to document 1

--------epsで別名で保存

save activDoc in file saveEpsFileName as eps with options ¬

{class:EPS save options ¬

, include document thumbnails:false ¬

, save multiple artboards:false ¬

, overprint:preserve ¬

, PostScript:level 2 ¬

, preview:none ¬

, embed linked files:false ¬

, embed all fonts:false ¬

, compatible gradient printing:false ¬

, compatibility:Illustrator 8 ¬

, CMYK PostScript:true ¬

, artboard range:1 ¬

}

--------PNG24を書き出し

export activDoc to file savePngFileName as PNG24 with options ¬

{class:PNG24 export options ¬

, antialiasing:true ¬

, artboard clipping:true ¬

, matte:false ¬

, matte color:{red:255, green:255, blue:255} ¬

, saving as HTML:false ¬

, transparency:true ¬

, horizontal scaling:72.0 ¬

, vertical scaling:72.0 ¬

}

--------アクティブドキュメントを保存しないで閉じる

close document 1 saving no

end tell

end repeat

end tell

end open

to replace(theText, orgStr, newStr)

set oldDelim to AppleScript's text item delimiters

set AppleScript's text item delimiters to orgStr

set tmpList to every text item of theText

set AppleScript's text item delimiters to newStr

set tmpStr to tmpList as text

set AppleScript's text item delimiters to oldDelim

return tmpStr

end replace

ドロップレット形式です。
「Illustrator.app.zip」をダウンロード
 

色分けされたリッチテキストで見る
「Illustrator.rtf」をダウンロード

「Illustrator.applescript.txt」をテキストで見る

このファイルはCC0を選択しています。


CC0についてはこちらを読んでみてください。