[Ai]AppleScriptでとにかく印刷しちゃう: [FORCE]

[Ai]AppleScriptでとにかく印刷しちゃう

いっぱいファイルがあって
それを
全部印刷しなくちゃいけないとき用

自分用につきエラー制御いっさい無し..w
（実は暑中見舞い用..w）

ドロップレット形式
10.6x
Adobe Illustrator CS4

ポイントは『プリント・プリセット』です。

ちょっと分りにくいとは思いますが

１で設定済みの『プリントプリセット』を調べて
２で選んでその設定で印刷する

って流れです。

そんなわけですので
『適切なプリントプリセット』を作ってから
って事になります。

v10の頃は必ずダイアログからしか
印刷出来なかったような気がしますが
便利になりました。

プリセットを使わない場合は
チマチマ全部設定になります....w
でも
参考にはなるとおもうんですが...

on open DropObj
--------------------ファインダ呼び出し
tell application "Finder"
-----------------ファインダ　アクティブ
activate
--------プリセットで印刷するか詳細設定を使うかの判定
display dialog "詳細設定で印刷かプリセットか選択" buttons {"詳細設定", "プリセット"} with icon 1 default button 1
---詳細は２プリセットは１を判定用に格納
if button returned of the result is "詳細設定" then
set the NameSelect to "2" as Unicode text
else if button returned of the result is "プリセット" then
--------プリントのプリセット名を指定
tell application "Adobe Illustrator"
--------プリントのプリセット名をリスト形式で格納
set PrintPriset to print presets as list
end tell
----プリセットを選ぶダイアログを出す
set chooseResult to choose from list PrintPriset ¬
with prompt "プリセットを選んでください" OK button name "実行する" with title "プリセット選択"
---戻り値を格納
copy the result as list to {the PrintPriset}

set the NameSelect to "1" as Unicode text
end if
-----------------繰り返しの始まり
repeat with ObjFiles in DropObj

-----------------ファイル名を取得
set fileName to name of ObjFiles as string

---------------パスを取得
set pathAliasDoc to ObjFiles as alias

---------------パスを文字列に変換
set pathStringDoc to pathAliasDoc as string

---------------拡張子を判定
set exeName to name extension of ObjFiles

----------------------ファイル名から拡張子を取り除く
set MainFileName to my replace(fileName, "." & exeName, "") as string

------フルパスからファイル名を抜いてディレクトリ名を作る
set pathStringDirName to my replace(pathStringDoc, fileName, "") as string

----------------psファイル名を定義
set the PSFileName to the (the MainFileName & "." & "ps") as string

---------------ps用パスにしておく
set savePSFileName to (pathStringDirName & ":" & PSFileName) as string





-----------------Illustrator呼び出し
tell application "Adobe Illustrator"

-----------------Illustrator　アクティブ
activate

---------------------------ファイルを開く
open pathAliasDoc without dialogs

------------------開いたファイルをactivDocとして定義
set activDoc to document 1

if NameSelect is "1" then
---------------------プリント（プリセット指定の場合）		
set printPre to PrintPriset as Unicode text
print activDoc options ¬
{class:print options ¬
, print preset:printPre ¬
}

else if NameSelect is "2" then
---------【ユーザー設定項目】	
---カラープロファイル名
set ColorProName to "Japan Color 2001 Coated" as Unicode text
---プリンタ名
set PrinterName to "Adobe PDF 8.0" as Unicode text
---PPD名
set PPDName to "Adobe PDF 9.0 J" as Unicode text
---透明の分割プリセット
set FlPreNmae to "" as Unicode text
---プリントジョブ名
set PrintJobName to MainFileName as Unicode text
---ジョブのパス
set JobFilePath to savePSFileName as Unicode text

---用紙名
set PaperName to "A3" as Unicode text
---用紙回転（false/true ）
set PaperTrans to (true)
---印字向き (landscape/portrait/reverse landscape/reverse portrait) 
set PrintOrientatio to (reverse landscape)



---------------------プリント（詳細指定の場合）
print activDoc options ¬
{class:print options ¬
, printer name:PrinterName ¬
, PPD name:PPDName ¬
, flattener preset:FlPreNmae ¬
¬
, font settings:¬
{class:font options ¬
, download fonts:subset ¬
, font substitution kind:oblique substitution ¬
} ¬
, color management settings:¬
{class:color management options ¬
, intent:relative colorimetric ¬
, name:ColorProName ¬
, profile kind:source profile ¬
} ¬
, color separation settings:¬
{class:color separation options ¬
, convert spot colors:false ¬
, over print black:false ¬
, separation mode:composite ¬
} ¬
, coordinate settings:¬
{class:coordinate options ¬
, emulsion:false ¬
, fit to page:false ¬
, orientation:PrintOrientatio ¬
, position:center ¬
, tiling:single full page ¬
, horizontal scale:100 ¬
, vertical scale:100 ¬
} ¬
, job settings:¬
{class:job options ¬
, name:PrintJobName ¬
, file path:JobFilePath ¬
, collate:false ¬
, copies:1 ¬
, designation:visible printable layers ¬
, print all artboards:true ¬
, print area:artboard bounds ¬
, print as bitmap:false ¬
, bitmap resolution:600.0 ¬
, reverse pages:false ¬
} ¬
, flattener settings:¬
{class:flattening options ¬
, clip complex regions:false ¬
, convert strokes to outlines:false ¬
, convert text to outlines:false ¬
, flattening balance:100 ¬
, gradient resolution:600.0 ¬
, overprint:preserve ¬
, rasterization resolution:600.0 ¬
} ¬
, page marks settings:¬
{class:page marks options ¬
, bleed offset:{0, 0, 0, 0} ¬
, marks offset:{0, 0, 0, 0} ¬
, page marks style:Japanese style ¬
, registration marks:false ¬
, page info marks:false ¬
, color bars:false ¬
, trim marks:false ¬
, trim marks weight:0.125 ¬
} ¬
, paper settings:¬
{class:paper options ¬
, name:PaperName ¬
, offset:0.0 ¬
, transverse:PaperTrans ¬
, height:0.0 ¬
, width:0.0 ¬
} ¬
, postscript settings:¬
{class:postscript options ¬
, PostScript:level 3 ¬
, binary printing:false ¬
, shading resolution:600.0 ¬
, negative printing:false ¬
, image compression:none ¬
, force continuous tone:false ¬
, compatible shading:false ¬
} ¬
}

end if



----------------------アクティブドキュメントを保存しないで閉じる
close activDoc saving no
----------------------イラストレーターを解放
end tell
end repeat
end tell
end open

-----------------------------文字の置き換えのサブルーチン
to replace(theText, orgStr, newStr)
set oldDelim to AppleScript's text item delimiters
set AppleScript's text item delimiters to orgStr
set tmpList to every text item of theText
set AppleScript's text item delimiters to newStr
set tmpStr to tmpList as text
set AppleScript's text item delimiters to oldDelim
return tmpStr
end replace