[Ai]AppleScriptでPDF書き出し（全オプション入りw）: [FORCE]

[Ai]AppleScriptでPDF書き出し（全オプション入りw）

例によって
自分用ですので（言い訳がましいか...汗）
エラー制御無しです。

好みの問題ですが
PDFファイル名とか作るときに
いちど
『ディレクトリ』+『ファイル名』+『.』+『拡張子』
的な
考え方の方が好きなんだよね

もちろん
拡張子をpdfに置き換えるだけの方が速いよね

でも
なんか
パス情報を一旦、分解する方法の方が好き..w

サンプルはドロップレット形式

イラストレーターで開いて（ダイアログ出さずに）
PDFに別名保存（セキュリティかけます）
開いたファイルはそのまま閉じる（保存しない）
な
内容
オプションを
全て（PDFX用の３つは使わな無かったけど）
記載していますので
参考になる人もいるかと思います。

10.6x
Adobe Illustrator CS4

on open DropObj
--------------------------------------------------ファインダ呼び出し
tell application "Finder"

--------------------------------------------------ファインダ　アクティブ
activate
--------------------------------------------------繰り返しの始まり
repeat with ObjFiles in DropObj

--------------------------------------------------ファイル名を取得
set fileName to name of ObjFiles as string

------------------------------------------------パスを取得
set pathAliasDoc to ObjFiles as alias

------------------------------------------------パスを文字列に変換
set pathStringDoc to pathAliasDoc as string

------------------------------------------------拡張子を判定
set exeName to name extension of ObjFiles

--------------------------------------------------ファイル名から拡張子を取り除く
set MainFileName to my replace(fileName, "." & exeName, "") as string

------------------------フルパスからファイル名を抜いてディレクトリ名を作る
set pathStringDirName to my replace(pathStringDoc, fileName, "") as string

----------------PDFファイル名を定義(PDF書き出しするので拡張子をpdfに変更）
set the PDFFileName to the (the MainFileName & "." & "pdf") as string

---------------PDF用にディレクトリ名とファイル名をつないでパスにしておく
set savePDFFileName to (pathStringDirName & ":" & PDFFileName) as string





--------------------------------------------------Illustrator呼び出し
tell application "Adobe Illustrator"

--------------------------------------------------Illustrator　アクティブ
activate

--------------------------------------------------ファイルを開く
open pathAliasDoc without dialogs

------------------開いたファイルをactivDocとして定義
set activDoc to document 1
----------一部のPDFプリセットの内容をここで定義します。（このやり方は好みの問題）
set RegistName to "force4u" as Unicode text
set ArtRange to "" as Unicode text
set pdfXCom to "" as Unicode text
set pdfXID to "" as Unicode text
set pdfXPro to "" as Unicode text
set pdfXStdDesc to "PDFX None" as Unicode text
----------------
set perPass to "8888" as Unicode text
set docPass to "9999" as Unicode text
----------------以下３つのオプションは使わなかった（PDFXな人は使いますね）
set FlatPre to "" as Unicode text
set FlatSet to "" as Unicode text
set PDFpre to "" as Unicode text
-------, flattener preset:FlatPre ¬
-------, flattener settings:FlatSet ¬
-------, PDF preset:PDFpre ¬
---------------------PDFで別名で保存		
save activDoc in file savePDFFileName as pdf with options ¬
{class:PDF save options ¬
, compatibility:Acrobat 8 ¬
, artboard range:ArtRange ¬
¬
, font subset threshold:100.0 ¬
, compress art:false ¬
, optimization:true ¬
, printer resolution:600.0 ¬
, preserve editability:false ¬
¬
, color conversion id:color conversion repurpose ¬
, color destination id:color dest working cmyk ¬
, color profile id:include all profiles ¬
¬
, pdfXstandard:PDFX None ¬
, pdfXstandard descripton:pdfXStdDesc ¬
, output condition:pdfXCom ¬
, output condition id:pdfXID ¬
, output intent profile:pdfXPro ¬
¬
, color compression:ZIP8bit ¬
, color downsampling:600.0 ¬
, color downsampling threshold:600.0 ¬
, color resample:nodownsample ¬
, color tile size:128 ¬
¬
, grayscale compression:ZIP8bit ¬
, grayscale downsampling:600.0 ¬
, grayscale downsampling threshold:600.0 ¬
, grayscale resample:nodownsample ¬
, grayscale tile size:128 ¬
¬
, monochrome compression:ZIP ¬
, monochrome downsampling:600.0 ¬
, monochrome downsampling threshold:600.0 ¬
, monochrome resample:nodownsample ¬
¬
, offset:0.0 ¬
, page marks style:Japanese style ¬
, color bars:true ¬
, trim marks:true ¬
, trim mark weight:trimmarkweight0125 ¬
, registration marks:true ¬
, trapped:false ¬
, bleed link:true ¬
, bleed offset:{0, 0, 0, 0} ¬
, registry name:RegistName ¬
¬
, acrobat layers:true ¬
, generate thumbnails:false ¬
, view pdf:false ¬
, page info:true ¬
¬
, require doc password:false ¬
, require perm password:true ¬
¬
, permission password:perPass ¬
, document password:docPass ¬
¬
, enable access:true ¬
, enable copy:false ¬
, enable plaintext:true ¬
, enable copy and access:false ¬
, allow printing:pdf 128 print none ¬
, changes allowed:pdf 128 no changes ¬
¬
}
----------------------アクティブドキュメントを保存しないで閉じる
close document 1 saving no
----------------------イラストレーターを解放
end tell
end repeat
end tell
end open

-----------------------------文字の置き換えのサブルーチン
to replace(theText, orgStr, newStr)
set oldDelim to AppleScript's text item delimiters
set AppleScript's text item delimiters to orgStr
set tmpList to every text item of theText
set AppleScript's text item delimiters to newStr
set tmpStr to tmpList as text
set AppleScript's text item delimiters to oldDelim
return tmpStr
end replace