[AppleScript]YouTubeのBloggerボタンの代わり【Google Chrome専用】

↑このボタンの代わりです
ここのBloggerボタンで記事を書こうとすると
FlashPlayerのiflameタイプのHTMLになるので
これをサムネイル画像と通常リンクに変えます

ポイントはここ

URLエンコードに渡す値（HTMLのタグ）ですが
＼バックスラッシュのエスケープを＼＼＼と３つにする所かな？たぶん

(*

YouTubeのBloggerボタンのサムネイルイメージのリング版

YoutubeのBloggerボタンがFlashのエンベットなので作りましたのよ

*)

--------------------------全面のURLを取得

tell application "Google Chrome"

activate

--------------URLの取得

set theURL to URL of active tab of window 1 as text

--------------タイトルの取得

set theTitle to title of active tab of window 1 as text

end tell

--------------VideoIDを取得

set theVidCom to "echo " & quoted form of theURL & "| awk -F \"v=\" '{print($2)}' |awk -F \"&\" '{print($1)}' " as text

set theVid to do shell script theVidCom as text

--------------設定項目：bloggerのポスト用のURL

set theBloggerUrl to "http://www.blogger.com/blog-this.g?"

--------------画像ファイルのURL お好みで

--90x120--set theImgUrl to "http://i4.ytimg.com/vi/" & theVid & "/default.jpg"

--180x320--set theImgUrl to "http://i4.ytimg.com/vi/" & theVid & "/mqdefault.jpg"

--360x480

set theImgUrl to "http://i4.ytimg.com/vi/" & theVid & "/hqdefault.jpg"

--maxresdefault.jpgは取得出来ないビデオ（ちょっと古いアップロードな物）があります

----set theImgUrl to "http://i4.ytimg.com/vi/" & theVid & "/maxresdefault.jpg"

--------------短縮URL

set theShortUrl to "http://youtu.be/" & theVid

--------------タグを用意　ここはお好みで　エスケープの\は\\\で

set theHtmlLine1 to "<div style=\\\"display: block; margin: auto;\\\">"

set theHtmlLine2 to "<a rel=\\\"nofollow\\\" href=\\\"" & theShortUrl & "\\\" class=\\\"youtubelink\\\" title=\\\"" & theTitle & "\\\">"

set theHtmlLine3 to "<img src=\\\"" & theImgUrl & "\\\" border=\\\"0\\\" class=\\\"youtubelinkimg\\\" alt=\\\"" & theTitle & "\\\" /></a>"

set theHtmlLine4 to "</div>"

--------------HTMLタグを整形

set theHtmlLine to (theHtmlLine1 & theHtmlLine2 & theHtmlLine3 & theHtmlLine4) as text

--------------HTMLをurlエンコード

set theUrlDecodeHtml to do shell script "php -r 'echo urlencode(\"" & theHtmlLine & "\");'"

--------------イメージのURLをエンコード

set theUrlDecodeImgUrl to do shell script "php -r 'echo urlencode(\"" & theImgUrl & "\");'"

--------------タイトルをエンコード

set theUrlDecodeTitle to do shell script "php -r 'echo urlencode(\"" & theTitle & "\");'"

--------------ダイアログ用に\\\になっているエスケープを\にする

set theHtmlLine to my replace(theHtmlLine, "\\", "") as text

--------------開く用のURLを整形

set theBloggerUrl to theBloggerUrl & "n=" & theUrlDecodeTitle & "&b=" & theUrlDecodeHtml & "&eurl=" & theUrlDecodeImgUrl

--------------クロームで開く

tell application "Google Chrome"

activate

make new window

tell window 1

tell active tab

open location theBloggerUrl

end tell

end tell

end tell

--------------その後でダイアログにHTML部分だけ表示する

tell application "Finder"

activate

display dialog "HTMLが出来ました" default answer the theHtmlLine with icon 1 with title "HTMLが出来ました" default button 1

end tell

--------------文字の置き換えサブルーチン

to replace(theText, orgStr, newStr)

set oldDelim to AppleScript's text item delimiters

set AppleScript's text item delimiters to orgStr

set tmpList to every text item of theText

set AppleScript's text item delimiters to newStr

set tmpStr to tmpList as text

set AppleScript's text item delimiters to oldDelim

return tmpStr

end replace

　
「YouTubeBloggerUrlGoogleChromev1.rtf」をダウンロード

　
　「YouTubeBloggerUrlGoogleChromev1.scpt.zip」をダウンロード